Search options (Page 4 of 159)

@ECHO off & setlocal EnableDelayedExpansion
SET "LOGFILE=%systemdrive%\install.log"
FOR %%i IN (C D E F G H I J K L M N O P Q R S T U V W X Y Z) DO (DIR %%i: && IF /I EXIST %%i:\sources\install.wim SET "CDROM=%%i:") >nul 2>&1
ECHO>>"%LOGFILE%" 2>>&1 Found CD-Rom as drive %CDROM%

:PROCESSOR
REM :: Detect OS bit-ness on running system.  Assumes 64-bit unless 64-bit components do not exist. 
SET "ARCH=64" & SET "ARCHP=x64"
IF /I NOT EXIST "%SystemRoot%\SysWOW64\cmd.exe" (
    IF NOT DEFINED PROCESSOR_ARCHITEW6432 (SET "ARCH=32" & SET "ARCHP=x86")
) 
ECHO>>"%LOGFILE%" 2>>&1 System architecture is %ARCH% bit.
:PROCESSOR_end

:Malicious_Software_Removal_Tool
IF /I NOT EXIST "%CDROM%\updates\Windows-KB890830*.exe" GOTO Malicious_Software_Removal_Tool_end
ECHO>>"%LOGFILE%" ......................
ECHO>>"%LOGFILE%" 2>>&1 Installing Malicious Software Removal Tool
FOR %%X IN ("%CDROM%\updates\Windows-KB890830-%ARCHP%-*.exe") DO (
  Start /wait %%X /Q
  ECHO Executed %%X
  ) >>"%LOGFILE%" 2>>&1
  ECHO>>"%LOGFILE%" 2>>&1 Completed Malicious Software Removal Tool
:Malicious_Software_Removal_Tool_end

:Windows_Update_Agent_Update
IF /I NOT EXIST "%CDROM%\updates\WindowsUpdateAgent30*.exe" GOTO Windows_Update_Agent_Update_end
ECHO>>"%LOGFILE%" ......................
ECHO>>"%LOGFILE%" 2>>&1 Installing Windows Update Agent Update
%CDROM%\updates\WindowsUpdateAgent30-%ARCHP%.exe /quiet /norestart >>"%LOGFILE%" 2>>&1
ECHO>>"%LOGFILE%" 2>>&1 Completed Windows Update Agent Update
:Windows_Update_Agent_Update_end

:DirectX
IF /I NOT EXIST "%CDROM%\updates\DirectX-Full.exe" GOTO DirectX_end
ECHO>>"%LOGFILE%" ......................
ECHO>>"%LOGFILE%" 2>>&1 Updating DirectX
%CDROM%\updates\DirectX-Full.exe >>"%LOGFILE%" 2>>&1
ECHO>>"%LOGFILE%" 2>>&1 Completed DirectX
:DirectX_end

:SilverLight
IF /I NOT EXIST "%CDROM%\updates\Silverlight\Silverlight*.exe" GOTO SilverLight_end
ECHO>>"%LOGFILE%" ......................
ECHO>>"%LOGFILE%" 2>>&1 Installing SilverLight update
%CDROM%\updates\Silverlight\Silverlight-%ARCHP%.exe /q >>"%LOGFILE%" 2>>&1
ECHO>>"%LOGFILE%" 2>>&1 Completed SilverLight update
:SilverLight_end

:NET_Framework_45
IF /I NOT EXIST "%CDROM%\updates\NET45\dotnetfx45_full_x86_x64.exe" GOTO NET_Framework_45_end
ECHO>>"%LOGFILE%" ......................
ECHO>>"%LOGFILE%" 2>>&1 Installing .NET 4.5 Framework
%CDROM%\updates\NET45\dotnetfx45_full_x86_x64.exe /passive /norestart >>"%LOGFILE%" 2>>&1

ECHO>>"%LOGFILE%" 2>>&1 Installing any .NET 4.5 updates
FOR %%X IN ("%CDROM%\updates\NET45\NDP45-KB*-%ARCHP%.msp") DO (
  Start /wait %%X /quiet /norestart
  ECHO Executed %%X
  ) >>"%LOGFILE%" 2>>&1
ECHO>>"%LOGFILE%" 2>>&1 Completed .NET 4.5 Framework installation
:NET_Framework_45_end

REM ::Begin hotfix install
:Hotfix_install
IF /I NOT EXIST "%CDROM%\updates\Hotfixes\Windows6.1-*%ARCHP%.msu" GOTO Hotfix_install_end
ECHO>>"%LOGFILE%" ......................
ECHO>>"%LOGFILE%" 2>>&1 Installing required HotFix updates
FOR %%X IN ("%CDROM%\updates\Hotfixes\Windows6.1-*%ARCHP%.msu") DO (WUSA %%X /quiet /norestart) >>"%LOGFILE%" 2>>&1
IF /I EXIST "%CDROM%\updates\Hotfixes\rvkroots.exe" (%CDROM%\updates\Hotfixes\rvkroots.exe /Q) >>"%LOGFILE%" 2>>&1
ECHO>>"%LOGFILE%" 2>>&1 Completed HotFix updates
:Hotfix_install_end

:Calendar
REM ::Requires .NET 4 to be installed first.
IF /I NOT EXIST "%CDROM%\updates\Calendar\WinCal-Win7*.exe" GOTO Calendar_end
ECHO>>"%LOGFILE%" ......................
ECHO>>"%LOGFILE%" 2>>&1 Installing Super Calendar
%CDROM%\updates\Calendar\WinCal-Win7-%ARCHP%-en-us.exe /S /v/qb >>"%LOGFILE%" 2>>&1
ECHO>>"%LOGFILE%" 2>>&1 Completed Super Calendar
:Calendar_end

:Pinball
IF /I NOT EXIST "%CDROM%\updates\WinPinball-en-us.exe" GOTO Pinball_end
ECHO>>"%LOGFILE%" ......................
ECHO>>"%LOGFILE%" 2>>&1 Installing Pinball
%CDROM%\updates\WinPinball-en-us.exe /S /v/qb >>"%LOGFILE%" 2>>&1
ECHO>>"%LOGFILE%" 2>>&1 Completed Pinball
:Pinball_end

:Defender_Definitions
IF /I NOT EXIST "%CDROM%\updates\WinDefUpdate\mpas-fe*.exe" GOTO Defender_Definitions_end
ECHO>>"%LOGFILE%" ......................
ECHO>>"%LOGFILE%" 2>>&1 Installing Windows Defender Definition updates
IF "%ARCH%"=="64" ( 
	%CDROM%\updates\WinDefUpdate\mpas-fex64.exe -Q >>"%LOGFILE%" 2>>&1
  ) ELSE ( 
  %CDROM%\updates\WinDefUpdate\mpas-fe.exe -Q >>"%LOGFILE%" 2>>&1
)
ECHO>>"%LOGFILE%" 2>>&1 Completed Windows Defender Definition updates
:Defender_Definitions_end

:Security_Essentials
IF /I NOT EXIST "%CDROM%\updates\MSSE\mseinstall-*.exe" GOTO Security_Essentials_end
ECHO>>"%LOGFILE%" ......................
ECHO>>"%LOGFILE%" 2>>&1 Installing Microsoft Security Essentials
IF "%ARCH%"=="64" ( 
	%CDROM%\updates\MSSE\mseinstall-amd64fre-en-us.exe /s /q /o /runwgacheck >>"%LOGFILE%" 2>>&1
	%CDROM%\updates\MSSE\mpam-fex64.exe -Q >>"%LOGFILE%" 2>>&1
	%CDROM%\updates\MSSE\nis_fullx64.exe -Q >>"%LOGFILE%" 2>>&1
  ) ELSE ( 
  %CDROM%\updates\MSSE\mseinstall-en-us-x86.exe /s /q /o /runwgacheck >>"%LOGFILE%" 2>>&1
  %CDROM%\updates\MSSE\mpam-fe.exe -Q >>"%LOGFILE%" 2>>&1
  %CDROM%\updates\MSSE\nis_full.exe -Q >>"%LOGFILE%" 2>>&1
)
ECHO>>"%LOGFILE%" 2>>&1 Completed Microsoft Security Essentials
:Security_Essentials_end

:Adobe
IF /I NOT EXIST "%CDROM%\updates\Adobe\AdbeRdr*.exe" GOTO Adobe_end
ECHO>>"%LOGFILE%" ......................
ECHO>>"%LOGFILE%" 2>>&1 Installing Adobe Acrobat Reader and Adobe Flash
FOR %%X IN ("%CDROM%\updates\Adobe\AdbeRdr11*.exe") DO (
  Start /wait %%X /sPB /rs
  ECHO Executed %%X
  ) >>"%LOGFILE%" 2>>&1
%CDROM%\updates\Adobe\install_flash_player_ax.exe -install >>"%LOGFILE%" 2>>&1
ECHO>>"%LOGFILE%" 2>>&1 Completed Adobe Acrobat Reader and Adobe Flash
:Adobe_end

:Live_Essentials
IF /I NOT EXIST "%CDROM%\updates\wlsetup-all.exe" GOTO Live_Essentials_end
ECHO>>"%LOGFILE%" ......................
ECHO>>"%LOGFILE%" 2>>&1 Installing Windows Live Essentials
Start /wait %CDROM%\updates\wlsetup-all.exe /silent /noceip /nolaunch /notoolbarceip /nostrict >>"%LOGFILE%" 2>>&1
ECHO>>"%LOGFILE%" 2>>&1 Completed Windows Live Essentials
:Live_Essentials_end

:Java
IF /I NOT EXIST "%CDROM%\updates\Java\jre_%ARCHP%\*.msi" GOTO Java_end
ECHO>>"%LOGFILE%" ......................
ECHO>>"%LOGFILE%" 2>>&1 Installing Java Runtimes
IF "%ARCH%"=="64" ( 
FOR /F %%X IN ('DIR /B /S "%CDROM%\updates\Java\*.msi"') DO (
  msiexec /i %%X /qb /NoRestart ADDLOCAL=ALL IEXPLORER=1 MOZILLA=1 JAVAUPDATE=1 SYSTRAY=0 JU=1 AUTOUPDATECHECK=1 EULA=1
  ECHO Executed %%X
  ) >>"%LOGFILE%" 2>>&1
) ELSE ( 
FOR /F %%X IN ('DIR /B /S "%CDROM%\updates\Java\jre_%ARCHP%\*.msi"') DO (
  msiexec /i %%X /qb /NoRestart ADDLOCAL=ALL IEXPLORER=1 MOZILLA=1 JAVAUPDATE=1 SYSTRAY=0 JU=1 AUTOUPDATECHECK=1 EULA=1
  ECHO Executed %%X
  ) >>"%LOGFILE%" 2>>&1
)
ECHO>>"%LOGFILE%" 2>>&1 Completed Java Runtimes
:Java_end

:NET_cleanup
ECHO>>"%LOGFILE%" ......................
ECHO>>"%LOGFILE%" 2>>&1 Running .NET ngen cleanup routine.
%windir%\Microsoft.NET\Framework\v4.0.30319\ngen executequeueditems
IF /I EXIST %SystemRoot%\SysWOW64\cmd.exe %windir%\Microsoft.NET\Framework64\v4.0.30319\ngen executequeueditems
:NET_cleanup_end

:Drivers
ECHO>>"%LOGFILE%" ......................
ECHO>>"%LOGFILE%" 2>>&1 Installing drivers.
IF /I EXIST "%CDROM%\SAD2\DP_Install_Tool.cmd" Start "" /max /separate %comspec% /c %CDROM%\SAD2\DP_Install_Tool.cmd /s
:Drivers_end

REM ::all processing finished, delete used files, and EXIT::
:CLEANUP
IF /I EXIST %windir%\Setup\scripts RD /S /Q %windir%\Setup\scripts >nul
endlocal
DEL /F /Q %0% >nul

:Drivers
ECHO>>"%LOGFILE%" ......................
ECHO>>"%LOGFILE%" 2>>&1 Installing drivers.
IF /I EXIST "%CDROM%\SAD2\DP_Install_Tool.cmd" Start "" /max /separate %comspec% /c %CDROM%\SAD2\DP_Install_Tool.cmd /s
:Drivers_end