Thanks for your answer about the driver naming. As I use a different method to integrate the driverpacks the method I use does not run the DPFinisher tool at the moment. Some time ago I was working on a new tool to parse the ini file and run the commands, but I have no complete code yet.
Do you have the source code of the DPFinisher program? It would help my project a bit.
When running the MarvellCleanup.cmd manually it failed with an access denied error and the registry keys were not removed.
I found on my system under HKLM\\SYSTEM\CurrentControlSet\Enum\Root\LEGACY_\0000
not only "Control", but also a "LogConf" directory. When permissions are not updated on both directories the Marvell driver cannot be removed.
Here's my modified version of the MarvellCleanup.cmd which fixes the issue.
::Delete Marvell drivers installed by DriverPacks.
::by fearless
::Requires MarvellCleanup.inf
:: WARNING: This script will indescriminately delete Marvell mass storage drivers
:: MV61XXMM, MV64XXMM, and MVXXMM. If DriverPacks was used to integrate mass
:: storage drivers into a Windows installation source, then those drivers will
:: always be installed whether needed or not.
@Echo Off
TITLE MarvellCleanup by fearless
Setlocal EnableExtensions
Set name=%~n0
Set iniRoot=\Registry\Machine
Set regRoot=HKLM
Set key=\SYSTEM\CurrentControlSet\Enum\Root\LEGACY_
Set subkey=0000 Control
Set subkey2=0000 LogConf
Set iniPerms="[1 8 17]"
Set initmp="%temp%\%name%.ini"
Set regdelarg=%iniRoot% %regRoot% %key% %iniPerms%
Call :regdel %regdelarg% MV61XXMM %subkey%
Call :regdel %regdelarg% MV61XXMM %subkey2%
Call :regdel %regdelarg% MV64XXMM %subkey%
Call :regdel %regdelarg% MV64XXMM %subkey2%
Call :regdel %regdelarg% MVXXMM %subkey%
Call :regdel %regdelarg% MVXXMM %subkey2%
Del %initmp%
Pushd "%~dp0"
rundll32 setupapi,InstallHinfSection DefaultInstall 132 .\%name%.inf
Popd
goto :EOF
:regdel
::Use regini to give Administrators full control then delete the key.
Echo.%1%3%5 %~4>%initmp%
If "%~6" NEQ "" Echo.%1%3%5\%6 %~4>>%initmp%
If "%~7" NEQ "" Echo.%1%3%5\%6\%7 %~4>>%initmp%
If "%~8" NEQ "" Echo.%1%3%5\%6\%7\%8 %~4>>%initmp%
If "%~9" NEQ "" Echo.%1%3%5\%6\%7\%8\%9 %~4>>%initmp%
regini %initmp%
Reg Delete %2%3%5 /fI don't know if other people experienced this problem, as I install the DriverPacks at a different moment during setup.
