Topic: nForce 430 / MCP61 RAID0 array not seen - VEN_10DE&DEV_03F6

Asus M2N68 PLUS motherboard with nForce 430 / MCP61 controller. Two drives configured in a RAID0 array from another nForce based board but the Windows won't boot until I change the controller drivers, and I'd like to access it without having to temporarily plug in a hard drive to install Windows on, just to access this data.

I'd manually tried using Asus Nvidia RAID drivers from their web page, and a newer version on the CD they provided (yea, weird, newer version on the disc), no luck. I then figured I'd give this driverpacks.net a try, and that's also not working. If I "Disable RAID Mode" the drive can be read in WinPE (I assume that puts it in IDE mode, not AHCI, hard to say as Asus BIOS option not very explanatory).

VEN_10DE&DEV_03F6&SUBSYS_83A4104&REV_A2

If anyone has any suggestions, they would be much appreciated.

Re: nForce 430 / MCP61 RAID0 array not seen - VEN_10DE&DEV_03F6

Can you try test pack #13 from this post? http://forum.driverpacks.net/viewtopic.php?id=4742
#13 will only work with your controller in RAID mode.
#14 will only work with your controller in IDE mode.

Read BEFORE you post.  HWID tool   DriverPacks Tutorial   DONATE!
http://driverpacks.net/userbar/admin-1.png
Not all heroes wear capes, some wear Kevlar!

Re: nForce 430 / MCP61 RAID0 array not seen - VEN_10DE&DEV_03F6

I was excited to see your suggestion; unfortunately when processing MassStorage.inf, it's producing a "Error: Cannot find folder: wxp" message. I found a stickied thread regarding this issue so I wiped out my PE, just in case I missed a file or folder, started with a fresh one, as well as a fresh dpbase folder and it's a no go.  I fought with this for about an hour before I posted... but I'm probably missing something simple.

Re: nForce 430 / MCP61 RAID0 array not seen - VEN_10DE&DEV_03F6

Well, only the folder wnt5 is created with this particular test pack because no other drivers are loaded, only the one nvidia folder.  The tests were really designed for normal disc-based installs, not BartPE.  But creating an empty wxp folder within the UBCD4Win\plugin\DriverPacks.net\MassStorage folder before building the PE disc should get rid of the error.  Maybe adding a w2k3 folder also would help.  I think those paths are hard-coded into the UBCD4win app.

Read BEFORE you post.  HWID tool   DriverPacks Tutorial   DONATE!
http://driverpacks.net/userbar/admin-1.png
Not all heroes wear capes, some wear Kevlar!

Re: nForce 430 / MCP61 RAID0 array not seen - VEN_10DE&DEV_03F6

a) Your suggestion to create the folder manually allowed me to create the disc.

b) Unfortunately, #13 does not work. It now detects that there's a volume, different behaviour from before; unfortunately the volume is reporting as being unreadable and corrupted and no imaging software will read it. This volume is perfectly healthy so the driver's not functioning quite right...

Any other ideas? (I appreciate your help, it feels like I'm moving towards some kind of solution)

Re: nForce 430 / MCP61 RAID0 array not seen - VEN_10DE&DEV_03F6

Well first off that Asus model doesn't have a nforce 430 chip but instead has a nforce 630a chip.
http://uk.asus.com/product.aspx?P_ID=fh … templete=2

Strange, as that driver is the original one recommended by nvidia for that model, but is not newest.
Both nvidia and Asus recommend v15.24 & 15.45 nforce packages
Maybe the clue is in how the RAID was created.  How did you build the array?  What software?  Was the RAID built on THAT board, or a different controller (yes, I read the original post)?
Typically RAID arrays only work properly on the exact controller they were created on.

Could you also try test pack #16 (from newer 15.45)?

Also, for some reason nvidia requires a registry entry set in the hive before the disc is created.  We haven't yet determined the best way to set that.

Read BEFORE you post.  HWID tool   DriverPacks Tutorial   DONATE!
http://driverpacks.net/userbar/admin-1.png
Not all heroes wear capes, some wear Kevlar!

Re: nForce 430 / MCP61 RAID0 array not seen - VEN_10DE&DEV_03F6

mr_smartepants wrote:

Typically RAID arrays only work properly on the exact controller they were created on.

mr_smartepants, I tested some motherboard to create test nvidia driverpacks and I can to confirm what RAID array works properly on all tested controllers.

Re: nForce 430 / MCP61 RAID0 array not seen - VEN_10DE&DEV_03F6

mr_smartepants wrote:

Maybe the clue is in how the RAID was created.  How did you build the array?  What software?  Was the RAID built on THAT board, or a different controller (yes, I read the original post)?

The array was created within the nvidia 'controller' RAID configuration pre-boot, not with Windows software.  The RAID array was built on a completely different board with a different onboard 'controller', which is why the system will not boot into Windows. I need to change the controller information.

mr_smartepants wrote:

Typically RAID arrays only work properly on the exact controller they were created on.

This array is healthy and fine, as it's perfectly accessible from a Windows 7 boot disc with no additional drivers. I deleted a pile of temp, temporary internet files and messed around a bit, then chkdsk'd and file system reports healthy.


mr_smartepants wrote:

Could you also try test pack #16 (from newer 15.45)?

I tried test pack #16, from the above link (if that's what you were referring to), and it does not detect the drive.

Pack #13 from above seems to detect drives that are NOT in a RAID array.

Re: nForce 430 / MCP61 RAID0 array not seen - VEN_10DE&DEV_03F6

urbanriot, can you try to run setPnpInterfaceNvgts.cmd from that post: http://forum.driverpacks.net/viewtopic. … 325#p30325 in i386 directory after slipstreaming?

Last edited by Debugger (2010-10-20 05:41:24)

Re: nForce 430 / MCP61 RAID0 array not seen - VEN_10DE&DEV_03F6

Forget about PE for a moment, What about a normal disc-based install.  Do any of the test packs work in that scenario?

Debugger wrote:

urbanriot, can you try to run setPnpInterfaceNvgts.cmd from that post: http://forum.driverpacks.net/viewtopic. … 325#p30325 in i386 directory after slipstreaming?

Isn't that what I said about three posts above? wink

Read BEFORE you post.  HWID tool   DriverPacks Tutorial   DONATE!
http://driverpacks.net/userbar/admin-1.png
Not all heroes wear capes, some wear Kevlar!

Re: nForce 430 / MCP61 RAID0 array not seen - VEN_10DE&DEV_03F6

mr_smartepants, yes smile I was a little wrong, PnpInterface key is necessary both for nvrd32, and for nvgts. Not for nvgts only.

Re: nForce 430 / MCP61 RAID0 array not seen - VEN_10DE&DEV_03F6

Debugger wrote:

urbanriot, can you try to run setPnpInterfaceNvgts.cmd from that post: http://forum.driverpacks.net/viewtopic. … 325#p30325 in i386 directory after slipstreaming?

I'm kind of mucking about with PE discs more than I'm needing to do any kind of slipstreaming... in fact, I don't need to slipstream at all, I'd F6 with USB floppy drive. I'd just like to get this going on a disc so I can convert the Windows controller driver on the array... I'm close to giving up, as I can simply access with a Windows Vista / 7 PE disc and copy the data that way, but I'd like to get my trusty old XP PE discs working here and make Windows boot... but I need PE accessing it first.

Is there any way to 'integrate' that command into my PE disc?  Or is there another storage controller driver pack I should try outside of the two suggested above?

Re: nForce 430 / MCP61 RAID0 array not seen - VEN_10DE&DEV_03F6

All you need to do is to slipstream test pack #16 and to create in any text editor this text file with any filename and with .cmd extension:

copy setupreg.hiv setupreg.hiv.%random%.sav
reg.exe unload HKLM\loaded_SYSTEM
reg.exe load HKLM\loaded_SYSTEM setupreg.hiv
reg.exe add "HKLM\loaded_SYSTEM\ControlSet001\Services\nvgts\Parameters\PnpInterface" /f /t REG_DWORD /v "5" /d 1
reg.exe unload HKLM\loaded_SYSTEM

Then place it to i386 folder of your slipstreamed disc and start.

the thing is that without this registry key is the hard drive will not be detected regardless of any test pack.

Re: nForce 430 / MCP61 RAID0 array not seen - VEN_10DE&DEV_03F6

urbanriot wrote:

The RAID array was built on a completely different board with a different onboard 'controller'

Which different onboard 'controller' did you use?
Did you used nvraid.sys or nvgts.sys at different onboard 'controller'?
Does nvgts.sys read a RAID created by nvraid.sys?

urbanriot wrote:

I need to change the controller information.

Nice a volunteer. I prepared a fix_hdc update years ago, supporting nvgts.
Never tested because of missing hardware.
You have to boot a PE first.

urbanriot wrote:

I'd F6 with USB floppy drive

You may use F6 with USB floppy at UBCD4Win.
Create a new UBCD4Win: don't add mass storage drivers. Boot and load F6 drivers.

urbanriot wrote:

Is there any way to 'integrate' that command into my PE disc?

Either edit setupreg.hiv as suggested. Buit compare file names.

Or add settings as a PEBuilder plugin.
Compare http://forum.driverpacks.net/viewtopic. … 133#p31133
Back then names nvgts, nvgts5 and nvgts6 was added.
You may have to adjust old plugin to current used file name.

Re: nForce 430 / MCP61 RAID0 array not seen - VEN_10DE&DEV_03F6

Sorry I've taken so long to reply to everyone's post, but it's been a busy week. I realize a number of you tried to help me, but I'm having a slight bit of difficulty understanding what some people have suggested.

cdob wrote:
urbanriot wrote:

The RAID array was built on a completely different board with a different onboard 'controller'

Which different onboard 'controller' did you use?

Unsure of the exact model, sorry, I'm not the one who originally did this. It was obviously nvidia, otherwise I wouldn't be able to read the RAID array from a Windows 7 disc.

cdob wrote:

Did you used nvraid.sys or nvgts.sys at different onboard 'controller'?
Does nvgts.sys read a RAID created by nvraid.sys?

I'm not entirely sure if I can answer that?

cdob wrote:
urbanriot wrote:

I need to change the controller information.

Nice a volunteer. I prepared a fix_hdc update years ago, supporting nvgts.
Never tested because of missing hardware.
You have to boot a PE first.

I would be very interested in trying your update! (But as you said, other problem to solve first).  How do obtain it?  I was going to attempt the one in UBCD.

cdob wrote:
urbanriot wrote:

I'd F6 with USB floppy drive

You may use F6 with USB floppy at UBCD4Win.
Create a new UBCD4Win: don't add mass storage drivers. Boot and load F6 drivers.

Well, after all these years of using PE discs, I'd completely forgotten that you could F6! So, excited, I loaded up my floppy with the appropriate drivers and... "The file nvrd32.sys could not be found". I tried both drivers on Asus site and drivers on their disc (different versions), even the 'make floppy' tool they include. Argh!


cdob wrote:

You may have to adjust old plugin to current used file name.

I'll try to reinterpret your suggestions tomorrow, after I've had more sleep and report back afterwards. I'm working on a week with little sleep, and I'm not entirely sure I understand, but I'm hopeful I'll figure it out.  Thank you!

Re: nForce 430 / MCP61 RAID0 array not seen - VEN_10DE&DEV_03F6

urbanriot wrote:

Unsure of the exact model, sorry, I'm not the one who originally did this. It was obviously nvidia, otherwise I wouldn't be able to read the RAID array from a Windows 7 disc.

Windows 7 CriticlaDeviceDatabase PCI#VEN_10DE&DEV_03F6&CC_0104 is connected to nvstor.
Windows 7 CriticlaDeviceDatabase *_NVRAIDBUS is connected to nvstor.

Nvidia XP drivers used a driver pair nvata.sys and nvraid.sys in the past.
And files nvgts.sys and nvrd32.sys currently.

Asus offers nvgts.sys and nvrd32.sys  too.

Which Windows XP driver relates to Windows 7 nvstor.sys?

urbanriot wrote:

I would be very interested in trying your update! (But as you said, other problem to solve first).  How do obtain it?  I was going to attempt the one in UBCD.

Sorry, it's at localhost so far only. Never tested so far.
Txtsetup.sif is processed to detect a valid driver. Idea: boot PE first and insert current used driver.
Therefore: fix_hdc won't insert a proper driver without a proper txtsetup.sif

F6 USB floppy:
Did you used a PE without nvgts.sys?
Which USB floppy do you use? Does XP txtsetup.sif contain USB floppy HardwareID?
http://support.microsoft.com/kb/916196
http://www.msfn.org/board/topic/82711-u … sb-floppy/

Are you familiar with offline registry?
There is another hint post #1565: http://www.msfn.org/board/topic/51140-i … _p__823780
Boot windows 7.
You have to load offline XP registry, adjust SYSTEM\CurrentControlSet to offline settings, import the registry settings.
Un load registry hive. And copy nvgts.sys and nvrd32.sys to system32\drivers\.

Re: nForce 430 / MCP61 RAID0 array not seen - VEN_10DE&DEV_03F6

cdob wrote:

Nvidia XP drivers used a driver pair nvata.sys and nvraid.sys in the past.
And files nvgts.sys and nvrd32.sys currently.

Small mistake - not nvata.sys, but nvatabus.sys. nvata.sys is ATA driver.

Re: nForce 430 / MCP61 RAID0 array not seen - VEN_10DE&DEV_03F6

Debugger wrote:

Small mistake - not nvata.sys, but nvatabus.sys. nvata.sys is ATA driver.

Thanks Debugger for debugging.

@urbanriot
Boot Windows 7 disc.
Which Nvidia RAID drivers are at hard disk at directory %SystemRoot%\system32\drivers ?

Not tested, no hardware:
Backup existing files.
Copy current driver files nvgts.sys and nvrd32.sys to %SystemRoot%\system32\drivers\

Run fix_nvgts_RAID.cmd at %SystemRoot%\system32\config\

@echo off
rem insert Nvidia nvgts RAID settings to offline registry
rem created by cdob
rem run at directory %SystemRoot%\system32\config\

copy system system.%random%.sav
reg.exe unload HKLM\loaded_SYSTEM >nul 2>&1
reg.exe load HKLM\loaded_SYSTEM SYSTEM 

rem detect CurrentControlSet
for /f "tokens=3" %%a in ('reg.exe query "HKLM\loaded_SYSTEM\Select" /v "Current"') do set /a ControlSet=%%a
set ControlSet=00000%ControlSet%
set ControlSet=ControlSet%ControlSet:~-3%
echo. &echo ControlSet "%ControlSet%" used.

set ClassGUID={4D36E97B-E325-11CE-BFC1-08002BE10318}
set CriticalDeviceDatabase=HKLM\loaded_SYSTEM\%ControlSet%\Control\CriticalDeviceDatabase
set Services=HKLM\loaded_SYSTEM\%ControlSet%\Services

echo on
@rem NVIDIA AHCI
reg.exe add "%CriticalDeviceDatabase%\PCI#VEN_10DE&CC_0106" /f /v "ClassGUID" /d "%ClassGUID%"
reg.exe add "%CriticalDeviceDatabase%\PCI#VEN_10DE&CC_0106" /f /v "Service" /d "nvgts"
@rem NVIDIA RAID
reg.exe add "%CriticalDeviceDatabase%\PCI#VEN_10DE&CC_0104" /f /v "ClassGUID" /d "%ClassGUID%"
reg.exe add "%CriticalDeviceDatabase%\PCI#VEN_10DE&CC_0104" /f /v "Service" /d "nvgts"

reg.exe add "%Services%\nvgts" /f /v "DisplayName" /d "NVIDIA nForce Serial ATA Driver"
reg.exe add "%Services%\nvgts" /f /v "Group" /d "SCSI miniport"
reg.exe add "%Services%\nvgts" /f /v "ImagePath" /d "system32\drivers\nvgts.sys"
reg.exe add "%Services%\nvgts" /f /t REG_DWORD /v "ErrorControl" /d 1
reg.exe add "%Services%\nvgts" /f /t REG_DWORD /v "Start" /d 0
reg.exe add "%Services%\nvgts" /f /t REG_DWORD /v "Type" /d 1

reg.exe add "%Services%\nvgts\Parameters\PnpInterface" /f /t REG_DWORD /v "5" /d 1


@rem RAID driver
reg.exe add "%CriticalDeviceDatabase%\SCSI#NVIDIA__Raid_Disk________" /f /v "ClassGUID" /d "%ClassGUID%"
reg.exe add "%CriticalDeviceDatabase%\SCSI#NVIDIA__Raid_Disk________" /f /v "Service" /d "nvrd32"
reg.exe add "%CriticalDeviceDatabase%\SCSI#__NVIDIA_______Raid_Disk" /f /v "ClassGUID" /d "%ClassGUID%"
reg.exe add "%CriticalDeviceDatabase%\SCSI#__NVIDIA_______Raid_Disk" /f /v "Service" /d "nvrd32"
reg.exe add "%CriticalDeviceDatabase%\SCSI#NVIDIA__Raid_Disk_20_____" /f /v "ClassGUID" /d "%ClassGUID%"
reg.exe add "%CriticalDeviceDatabase%\SCSI#NVIDIA__Raid_Disk_20_____" /f /v "Service" /d "nvrd32"
reg.exe add "%CriticalDeviceDatabase%\SCSI#__NVIDIA____Raid_Disk_20" /f /v "ClassGUID" /d "%ClassGUID%"
reg.exe add "%CriticalDeviceDatabase%\SCSI#__NVIDIA____Raid_Disk_20" /f /v "Service" /d "nvrd32"
reg.exe add "%CriticalDeviceDatabase%\*_NVRAIDBUS" /f /v "ClassGUID" /d "%ClassGUID%"
reg.exe add "%CriticalDeviceDatabase%\*_NVRAIDBUS" /f /v "Service" /d "nvrd32"
reg.exe add "%CriticalDeviceDatabase%\*NVRAIDBUS" /f /v "ClassGUID" /d "%ClassGUID%"
reg.exe add "%CriticalDeviceDatabase%\*NVRAIDBUS" /f /v "Service" /d "nvrd32"
reg.exe add "%CriticalDeviceDatabase%\*NVRAID20" /f /v "ClassGUID" /d "%ClassGUID%"
reg.exe add "%CriticalDeviceDatabase%\*NVRAID20" /f /v "Service" /d "nvrd32"

reg.exe add "%Services%\nvrd32" /f /v "DisplayName" /d "NVIDIA nForce RAID Driver"
reg.exe add "%Services%\nvrd32" /f /v "Group" /d "System Bus Extender"
reg.exe add "%Services%\nvrd32" /f /v "ImagePath" /d "system32\drivers\nvrd32.sys"
reg.exe add "%Services%\nvrd32" /f /t REG_DWORD /v "ErrorControl" /d 1
reg.exe add "%Services%\nvrd32" /f /t REG_DWORD /v "Start" /d 0
reg.exe add "%Services%\nvrd32" /f /t REG_DWORD /v "Type" /d 1

reg.exe add "%Services%\nvrd32\Parameters" /f /t REG_DWORD /v "BusType" /d 8

rem pause
reg.exe unload HKLM\loaded_SYSTEM

Last edited by cdob (2010-10-27 03:41:06)

Re: nForce 430 / MCP61 RAID0 array not seen - VEN_10DE&DEV_03F6

Cdob, if no one has told you lately, you're awesome. System is now working, life is good, woohoooo!!

Re: nForce 430 / MCP61 RAID0 array not seen - VEN_10DE&DEV_03F6

Yup, cdob is awesome! smile

Read BEFORE you post.  HWID tool   DriverPacks Tutorial   DONATE!
http://driverpacks.net/userbar/admin-1.png
Not all heroes wear capes, some wear Kevlar!

Re: nForce 430 / MCP61 RAID0 array not seen - VEN_10DE&DEV_03F6

urbanriot wrote:

System is now working, life is good, woohoooo!!

Thanks for report.
Always a pleasure to solve a riddle. Especial if half conditions are unknown.

I'm rather curious still: what did we accomplish really?

Rember the two Nvidia driver pairs:
old: nvatabus.sys and nvraid.sys
new: nvgts.sys and nvrd32.sys

There is used new driver pair at new hardware currently.

Unclear:
Does new driver pair support a RAID from old driver pair?

Question:
Does exist files nvatabus.sys and nvraid.sys at old RAID hard disks?

Re: nForce 430 / MCP61 RAID0 array not seen - VEN_10DE&DEV_03F6

cdob wrote:

I'm rather curious still: what did we accomplish really?

Well, now we know how to fix the nvidia problem with a registry hive modification.
This can be as simple as a batch file called by DriverPacks BASE during textmode integration (or directly coded) in a newer version of DriverPacks BASE.
But you're right.  Can the newer files work on older hardware?  That would be a good test.
@urbanriot, now that the hive has the correct fix, can you try the test packs again but in reverse order?  Highest number packs first (low#=old drivers, high#=new drivers) and post your results?  It would be very time consuming on your part but would provide VERY valuable feedback to us.

Read BEFORE you post.  HWID tool   DriverPacks Tutorial   DONATE!
http://driverpacks.net/userbar/admin-1.png
Not all heroes wear capes, some wear Kevlar!

Re: nForce 430 / MCP61 RAID0 array not seen - VEN_10DE&DEV_03F6

A generic low ranking HardwareID PCI\VEN_10DE&CC_0104 is used.
benefit: this match all nvidia RAID controllers.
drawback: this match all nvidia RAID controllers, even not supported ones

And ranking may load a old driver:

nforce 9.35 RAID txtsetup.oem

[HardwareIds.scsi.BUSDRV]
id = "PCI\VEN_10DE&DEV_03F6", "nvatabus"

nforce 15.46 RAID txtsetup.oem

[HardwareIds.scsi.BUSDRV]
id = "PCI\VEN_10DE&DEV_03F6", "nvgts"

Old and new driver match the same HardwareID.

Given a old motherboard with PCI\VEN_10DE&DEV_03F6:
CriticalDeviceDatase connect PCI\VEN_10DE&DEV_03F6 or PCI\VEN_10DE&DEV_03F6\* to nvatabus.

The same RAID transfered to a new motherboard with the same PCI\VEN_10DE&DEV_03F6:
After above simple fix both drivers are connected at CriticalDeviceDatase.
PCI\VEN_10DE&DEV_03F6* to nvatabus
PCI\VEN_10DE&CC_0104 to nvgts

PCI\VEN_10DE&DEV_03F6* has a higher priority.
Start=0 does load all 4 nvidia storage drivers.

Booting result is unkown.

Current approach should match most cases at real life.
A clean solution requires more work. I like testing results.
A working solution should be possible at all cases.
I'm looking forward to more user requests.

Edited:
Typo 104 106

Last edited by cdob (2010-10-29 18:31:24)