Search options

Here's some simple batch files that I've been using to integrate updates and drivers into all indexes of Win7 source files before building .iso.
I thought I'd share them for others.
Make sure to execute these batch files by right-clicking and selecting "Run as administrator".
Set the paths to whatever you like, just be sure to NOT use a trailing backslash in the path (i.e. C:\mnt instead of C:\mnt\ )
To download the patches, I use Windows Updates Downloader with current download lists from this post (not 100% complete, but a great start)

For drivers, I separate my folders into boot & main.  Boot drivers are integrated into the boot.wim (index 2) and for me only contain dpms. 

Enjoy!

.
.
.

And for you testing types, here's some experimental code for all NT6 OS (auto adjusts).  Code in-work.

@echo off
:: Do NOT use trailing backslash in paths (i.e. C:\mnt instead of C:\mnt\ )
:: Hardcoded paths (C:\etc) are acceptable, but discouraged in favor of flexible relative paths 
:: such as (%~dp0\ "the directory containing this script", or %cd% "current directory", or ..\..\ "back two directories")
:: Network shares (\\server\path) are not supported by this script.
::Set Paths to directories here.
:Path to mount folder
set "mnt=%~dp0mount"
:Path to temp folder
set "tmp=%~dp0temp"
:Path to source .wim files
set "src=%~dp0source"
:Path to driver folders (each should contain x86 & x64 folders)
set "driver-boot=%~dp0Drivers\Boot"
set "driver-main=%~dp0Drivers\Install"
::Do NOT modify anything below this line unless you know what you are doing!
:Environment checks
:DISM-check
IF NOT EXIST "%WINDIR%\SYSTEM32\DISM\DISMHOST.EXE" GOTO ERROR1
:WIM-check
IF NOT EXIST "%src%\*.wim" GOTO ERROR2
:Driver-check
IF NOT EXIST "%driver-boot%\*" GOTO ERROR3

:Index-start
set idx=1
:Index stop
set bootx=2
dism /get-wiminfo /wimfile:"%src%\install.wim" > "%tmp%\index.log"
dism /get-wiminfo /wimfile:"%src%\install.wim" /index:1 > "%tmp%\detail.log"
setlocal EnableDelayedExpansion
set "cmd=findstr /R /N "^^" "%tmp%\index.log" | find /C "Index""
for /f %%a in ('!cmd!') do set indexs=%%a
cls

echo %indexs% Install.wim indexes found.
:Arch detection
if exist "%tmp%\detail.log" (
  FOR /F "tokens=* skip=2 usebackq" %%a IN (`FIND "Architecture" "%tmp%\detail.log"`) DO (
  set str=%%a
  for /f "tokens=2 delims=: " %%b in ('echo !str!') do (
  set arch=%%b
  )) 
)
echo The install.wim architecture is %arch%
echo Using boot drivers from folder:%driver-boot%\%arch%
echo Using main drivers from folder:%driver-main%\%arch%
:begin-boot
echo Integrating Boot WIM Index: %idx%
Dism /Mount-Wim /WimFile:"%src%\BOOT.WIM" /index:%idx% /MountDir:"%mnt%"
Dism /image:"%mnt%" /Add-Driver /driver:"%driver-boot%\%arch%" /recurse /forceunsigned
Dism /Unmount-Wim /MountDir:"%mnt%" /commit
if "%idx%"=="%bootx%" set idx=1 & goto begin-install
set /a idx+=1
goto begin-boot
:begin-install
echo Integrating Install WIM Index: %idx%
Dism /Mount-Wim /WimFile:"%src%\install.WIM" /index:%idx% /MountDir:"%mnt%"
Dism /image:"%mnt%" /Add-Driver /driver:"%driver-main%\%arch%" /recurse /forceunsigned
dism /Unmount-Wim /MountDir:"%mnt%" /commit
if "%idx%"=="%indexs%" goto END
set /a idx+=1
goto begin-install
:End
echo .........................................
echo Driver integration complete.
:Cleanup
 cd %SYSTEMDRIVE%\
 IF EXIST "%tmp%\*" DEL /F /S /Q "%tmp%\*" >nul
echo Cleanup complete.
:Exit
pause
exit
:ERROR1
IF EXIST "%WINDIR%\SYSWOW64\DISM\DISMHOST.EXE" GOTO WIM-check
ECHO DISM utility not found.  Please install the Microsoft WAIK suite of utilities.
echo Windows® Automated Installation Kit (AIK) downloads
echo WAIK 3.0: http://www.microsoft.com/download/en/details.aspx?id=5753
echo WAIK 3.1 supplement: http://www.microsoft.com/download/en/details.aspx?id=5188
goto Exit
:ERROR2
IF EXIST "%src%\sources\*.wim" set "src=%src%\sources" & GOTO Driver-check
ECHO WIM files not detected.  Please check source directory.
goto Exit
:ERROR3
IF EXIST "%driver-main%\*" GOTO Index-start
ECHO Driver files not detected.  Please check driver directory.
goto Exit

Strange, I don't have that problem.

Ken@fri,
Thats why there is a option to delete or keep them in the script.  Of course if silent it will auto leave it but that might change with mr_smartepants new version to be released soon (I dont know).

(Battery)
reg query "HKEY_LOCAL_MACHINE\SYSTEM\CurrentControlSet\Control\Class\{72631E54-78A4-11D0-BCF7-00AA00B7B32A}\0000" && echo Laptop found!

or

(Portable Battery)
WMIC SystemEnclosure GET ChassisTypes
WMIC ComputerSystem GET PCSystemType

would work for lappys.    It looks for the battery value in the reg entry in the first example.  This would not work on image restore though just to let you know for that reg entry isnt included in images usually.  The second example gets its info from the SMBIOS tables off the motherboard which is the method I would prefer for some systems might not have the reg entry like from a image restore.

@ mr_smartepants this would be a good addon if ya will to only leave behind touchpad/HID if lappy present.

Well that would be fine if the "touchpad-HID" Third Party DriverPack included only drivers for laptops.  However that Third Party DriverPack includes drivers for mice and keyboards also.