I'll do what i can to see that into at least the current testing version of DPs_BASE.
Maybe mr_smartepants would update SAD3, if it pans out for BASE.

What more does Igor Pavlov's 7-zip v9.22 offer over v9.20?
Wim support, eh Jeff?

That might be just the inspiration OverFlow needs to start developing a NT6-compatible version of DPs_BASE!

I'm on a "need-to-know" basis here, btw.  :lol
_   _   _   _   _   _   _   _   _   _   _   _   _   _   _   _   _   _   _   _   _   _   
I've had no trouble whatsoever with the 9.20.0.2 revision of 7-zip32.dll specifically, even on older machines down to about !GHz-512MB.  Below that, certainly she be slow ... now even s l  o    w     e      r       .        .          .

It's rock solid stable though.  That is what one should be able to expect from any "Release" anyway, eh?

This revision of 9.20.0.2 has multi-core support, iirc, and supports LZMA2, amongst many other bugfixes & improvements.  It was a worthy successor of the 4.65 revision that was in there, iirc.

The packs i post are simply LZMA compressed for widest compatibility, btw.
That doesn't stop anybody from recompressing their own packs to LZMA2, if they have DPs_BASE v1109012b.

I should add that to docs...

Cheers and Regards

Cheers and Regards

EDIT:  With current downloads of v9.20 ALONE numbering 114,841,923, not counting the rest of the v9 series, or counting the other archiving programs that are also able to handle LZMA2 files such as HaoZip - http://www.haozip.com/Eng/index_en.htm, it sure seems that you should be able to consider being able to handle LZMA2 type files as a reasonable requirement.  And if you include a version of 7-Zip that's able to handle them with your release, then even that concern goes away.

Yeah, I saw that.  I grabbed both x64/x86 installers from the main site and extracted each 7z.exe & 7z.dll.
I thought the 9.22 was beta.

I knew you saw it - That remark was meant for OverFlow.  I didn't know if he saw it.  Since he mentioned using LZMA2 for x64 DP's and updating BASE I thought it might be useful for him.  Sorry for the misunderstanding.

9.22 is NOT marked as Beta anywhere I saw.

Cheers and Regards

Erik, while the standalone version you referenced, the 9.20 "7za" version, seems to be the latest available, you could also use the 7z console version, the "7z" version.  The 9.22 version is available here - http://sourceforge.net/projects/sevenzi … -Zip/9.22/.  To get them, you can install the version you want and copy the files out, either the x86 or x64, or just extract the files you need, using 7-zip of course.   The only files you need are "7z.exe" and "7z.dll", you just need to have them both from the x86  and/or x64 version.  They do not have to be installed or registered.  Put the .exe and the .dll in the same folder and you're good to go.  The 7z.exe is command line driven, which you can see the main command options by opening a command box in that folder and simply typing "7z" without the quotes.

The "7z.exe" plus "7z.dll" are larger than the 7za.exe standalone, but they are available in both x86 and x64 versions and they fully support LZMA2.

EDIT: Also, to be clear, the "7z.exe" plus "7z.dll" combination is fully capable of handling both compression and decompression chores.

Cheers and Regards

At the point I update BASE next i could easily add an updated dll ... Did i understand correctly that un7zip works fine with an updated dll?

I have so far had to babysit 7-zip to note time of archiving.  Does anyone know of a way to automate this?  If i had the slightest clue of the command-line settings, i would set up a batch of files to be compressed, & echo a text line & redirect to a file, so that i could calculate from file modifications times.  I'm not complaining; it's just difficult to get anything else done at the same time.

Here's a timing routine you're welcome to use.  I save it as TestTime.cmd, but you can use whatever name you want.

@ECHO OFF & SETLOCAL ENABLEEXTENSIONS ENABLEDELAYEDEXPANSION

(CALL :f_GetTime _StartTime)

::
:: Call the Routine here that you want to time
::
:: ping is an extraordinarily inaccurate, but simple delay for testing
:: the "3" will delay for ~2 seconds - this is just an example
:: REMOVE THIS "ping" LINE AND REPLACE IT WITH A CALL TO THE ROUTINE YOU WANT TO TIME!!
::

ping 127.0.0.1 -n 3 >nul 2>&1

(CALL :f_GetTime _EndTime)
(CALL :f_TimeDiff %_StartTime% %_EndTime% _TimeDiff)

::
:: At this point , the variable _TimeDiff will have the time that the Command
:: Routine took -- %_TimeDiff% will be set to the string HH:MM:SS.MSC
:: You can echo to the screen or redirect to a log file or use it however you like.
:: THIS IS ECHO'D TO THE SCREEN JUST AS AN EXAMPLE
::

echo %_TimeDiff%

ENDLOCAL&GOTO :EOF


:: #############################################################################
:: :f_GetTime _Time
::
:: Load time in a variable, zero padded using ONLY "standard" delimiters (:.)
::
:: Usage: CALL :f_GetTime _Time
::
:: %_Time% will be set to HH:MM:SS.MSC - NOTE: that MS is now THREE digits
::
:: Although the default time delimiter, in Windows XP and above is either . or :
:: users can change the delimiter to just about any character they like. And you
:: know theres always that one guy, the one who writes everything in green ink,
:: who will do this!  This script always returns HH:MM:SS.MSC, note that MS
:: is now 3 digits, no matter which time delimiter has been set in the control
:: panel. Based on a discussion at ss64.com, with input from avery_larry and
:: bluesxman, and tweaks by bphlpt using examples by Frank Westlake.
::
:: Dependencies: None
::
:: Upon exit, ERRORLEVEL is set to 0.
:: ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
::
:f_GetTime _Time
SETLOCAL ENABLEEXTENSIONS
FOR /F "tokens=1-3 delims=1234567890 " %%G IN ("%TIME%") DO (SET "_Delims=%%G%%H%%I")
FOR /F "tokens=1-4 delims=%_Delims% " %%G IN ("%TIME%") DO (SET "_hh=00%%G"&SET "_min=00%%H"&SET "_ss=00%%I"&SET "_ms=00%%J0")
ENDLOCAL&(SET %1=%_hh:~-2%:%_min:~-2%:%_ss:~-2%.%_ms:~-3%)&EXIT /B 0
::
:: #############################################################################

:: #############################################################################
:: :f_TimeDiff %_StartTime% %_EndTime% _TimeDiff
::
:: Subtract %_StartTime% from %_EndTime% and assign difference to _TimeDiff.
::
:: Usage: CALL :f_TimeDiff %_StartTime% %_EndTime% _TimeDiff
::
:: %_TimeDiff% will be set to HH:MM:SS.MSC - NOTE: that MS is now THREE digits.
::
:: Dependencies: None
::
:: Upon exit, ERRORLEVEL is set to 0.
:: ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
::
:f_TimeDiff %_StartTime% %_EndTime% _TimeDiff
SETLOCAL ENABLEEXTENSIONS
(CALL :f_ConvertTimeToMs %1 _StartTime)
(CALL :f_ConvertTimeToMs %2 _EndTime)
(SET /a "_DiffMs=%_EndTime%-%_StartTime%")
IF 0 GTR %_DiffMs% (SET /a "_DiffMs=%_DiffMs%+24*3600000")
(SET /a "_hh=(%_DiffMs%/3600000)")
(SET /a "_min=(%_DiffMs%/60000)-60*%_hh%")
(SET /a "_ss=(%_DiffMs%/1000)-3600*%_hh%-60*%_min%")
(SET /a "_ms=%_DiffMs%-1000*(%_DiffMs%/1000)")
(SET "_hh=00%_hh%"&SET "_min=00%_min%"&SET "_ss=00%_ss%"&SET "_ms=000%_ms%")
ENDLOCAL&(SET %3=%_hh:~-2%:%_min:~-2%:%_ss:~-2%.%_ms:~-3%)&EXIT /B 0
::
:: #############################################################################

:: #############################################################################
:: :f_ConvertTimeToMs %_Time% _TimeInMs
::
:: Convert a time to Ms.
::
:: Usage: CALL :f_ConvertTimeToMs %_Time% _TimeInMs
::
:: %_TimeInMs% will be set to the number of Ms in %_Time%.
::
:: Dependencies: None
::
:: Upon exit, ERRORLEVEL is set to 0.
:: ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
::
:f_ConvertTimeToMs %_Time% _TimeInMs
SETLOCAL ENABLEEXTENSIONS
(SET "_Ms=%1")
ENDLOCAL&(SET /a "%2=3600000*(1%_Ms:~0,2%-100)+60000*(1%_Ms:~3,2%-100)+1000*(1%_Ms:~6,2%-100)+(1%_Ms:~9,3%-1000)")&EXIT /B 0
::
:: #############################################################################

Cheers and Regards

Speaking of legacy systems, what is the minimum memory size to target for XP; 256MB, 192MB, 128MB (minimum recommendation of MS)?

To be safe, I build all the packs by keeping the lowest common denominator (XP 128MB RAM) in mind.  The packs may be larger than they could be, but I know someone with a low-end system won't have problems.

I'm not sure about logging the timestamps.